local kube = import "k8s/configs/base.libsonnet";
local linuxserver = import "k8s/configs/templates/core/linuxserver.libsonnet";
local images = import "k8s/configs/images.libsonnet";

local probe(delaySeconds) = {
  initialDelaySeconds: delaySeconds,
  periodSeconds: 30,
  tcpSocket: {
    port: "http",
  },
};

local WebPort = 5055;

local Params = kube.simpleFieldStruct([
  "namespace",
  "name",
  "filePath",
  "configClaimName",
]) {
  labels: {},
  gatekeeperSidecar: null,
  lsParams: linuxserver.AppParams {
    name: $.name,
    namespace: $.namespace,
    filePath: $.filePath,
    templatePath: std.thisFile,
    baseAppName: "overseerr",
    imageName: "linuxserver/overseerr",
    labels+: $.labels,
    gatekeeperSidecar: $.gatekeeperSidecar,
    services: [
      linuxserver.Service {
        suffix: "ui",
        spec: kube.SvcUtil.BasicHttpClusterIpSpec(WebPort)
      },
    ],
    ports: [ kube.DeployUtil.ContainerPort("http", WebPort), ],
    pvcs: [
      linuxserver.Pvc{
        name: "config",
        mountPath: "/app/config",
        bindName: $.configClaimName,
      },
    ],
    resources: {
      requests: {
        cpu: "50m",
        memory: "256Mi",
      },
      limits: {
        cpu: "200m",
        memory: "512Mi",
      },
    },
    livenessProbe: probe(/*delaySeconds=*/20),
    readinessProbe: probe(/*delaySeconds=*/20),
  },
};

local App(params) = linuxserver.App(params.lsParams) {
};


{
  Params: Params,
  WebPort: WebPort,
  App(params): App(params),
}